10D Gamma matrices and Identities

Definitions

Notation:  
(Subscript[Γ, m])=(({{0, ((((Subscript[γ, m])))^(αβ))}, {(Subscript[((Subscript[γ, m])), αβ]), 0}}))=(({{0, (Subscript[γt, m])}, {(Subscript[γ, m]), 0}}))  and  (Subscript[γ, mn])=(1/2)(Subscript[((((Subscript[γ, m])(Subscript[γt, n])-(m↔n)))^α), β])

Pauli matrix and Tensoring

FS=FullSimplify;
MF=MatrixForm;

σ[0]={{1,0},{0,1}};
σ[1]={{0,1},{1,0}};
σ[2]={{0,I},{-I,0}};
σ[3]={{1,0},{0,-1}};

Define the tensor product by
  (Subscript[(AB), IJ])=(Subscript[a, pq])(Subscript[b, PQ])  if  I=P+(p-1)dimB J=Q+(q-1)dimB'
where dimA = Length[A] dimA’=Length[Transpose[A]]. This operation is associative.

tensoring[m1_,m2_,mI_,mJ_]:=Module[{dRow=Length[m2],dCol=Length[Transpose[m2]],p1,q1,p2,q2},
p1=Ceiling[mI/dRow];
q1=Ceiling[mJ/dCol];
p2=Mod[mI-1,dRow]+1;
q2=Mod[mJ-1,dCol]+1;
m1[[p1,q1]]m2[[p2,q2]]
];
CircleTimes[m1_,m2_]:=Table[tensoring[m1,m2,mI,mJ],{mI,Length[m1]Length[m2]},{mJ,Length[Transpose[m1]]Length[Transpose[m2]]}];
CircleTimes[m1_,m2_,m3__]:=CircleTimes[CircleTimes[m1,m2],m3];

10D small and large Gamma matrices

Γ[1]=σ[1]⊗σ[2]⊗σ[2]⊗σ[1]⊗σ[3];
Γ[2]=σ[1]⊗σ[2]⊗σ[1]⊗σ[3]⊗σ[2];
Γ[3]=σ[1]⊗σ[2]⊗σ[3]⊗σ[2]⊗σ[1];
Γ[4]=σ[1]⊗σ[1]⊗σ[0]⊗σ[1]⊗σ[3];
Γ[5]=σ[1]⊗σ[1]⊗σ[3]⊗σ[0]⊗σ[1];
Γ[6]=σ[1]⊗σ[1]⊗σ[1]⊗σ[3]⊗σ[0];
Γ[7]=σ[1]⊗σ[1]⊗σ[3]⊗σ[3]⊗σ[3];
Γ[8]=σ[1]⊗σ[1]⊗σ[1]⊗σ[1]⊗σ[1];
Γ[9]=σ[1]⊗σ[3]⊗σ[0]⊗σ[0]⊗σ[0];
Γ[10]=σ[2]⊗σ[0]⊗σ[0]⊗σ[0]⊗σ[0];
Γ[0]=-I*Γ[10];
Γ[11]=Γ[0].Γ[1].Γ[2].Γ[3].Γ[4].Γ[5].Γ[6].Γ[7].Γ[8].Γ[9];

γ[1]=σ[2]⊗σ[2]⊗σ[1]⊗σ[3];
γ[2]=σ[2]⊗σ[1]⊗σ[3]⊗σ[2];
γ[3]=σ[2]⊗σ[3]⊗σ[2]⊗σ[1];
γ[4]=σ[1]⊗σ[0]⊗σ[1]⊗σ[3];
γ[5]=σ[1]⊗σ[3]⊗σ[0]⊗σ[1];
γ[6]=σ[1]⊗σ[1]⊗σ[3]⊗σ[0];
γ[7]=σ[1]⊗σ[3]⊗σ[3]⊗σ[3];
γ[8]=σ[1]⊗σ[1]⊗σ[1]⊗σ[1];
γ[9]=σ[3]⊗σ[0]⊗σ[0]⊗σ[0];
γ[10]=-I*σ[0]⊗σ[0]⊗σ[0]⊗σ[0];
γ[0]=-I*γ[10];

(* γt[i_]:=γt[i]=If[i==0||i==10,-1,1]*γ[i]; To avoid errors after parallelization *)
γt[1]=σ[2]⊗σ[2]⊗σ[1]⊗σ[3];
γt[2]=σ[2]⊗σ[1]⊗σ[3]⊗σ[2];
γt[3]=σ[2]⊗σ[3]⊗σ[2]⊗σ[1];
γt[4]=σ[1]⊗σ[0]⊗σ[1]⊗σ[3];
γt[5]=σ[1]⊗σ[3]⊗σ[0]⊗σ[1];
γt[6]=σ[1]⊗σ[1]⊗σ[3]⊗σ[0];
γt[7]=σ[1]⊗σ[3]⊗σ[3]⊗σ[3];
γt[8]=σ[1]⊗σ[1]⊗σ[1]⊗σ[1];
γt[9]=σ[3]⊗σ[0]⊗σ[0]⊗σ[0];
γt[10]=I*σ[0]⊗σ[0]⊗σ[0]⊗σ[0];
γt[0]=I*γ[10];

sigG[m_]:=If[m==0||m==10,-1,1];
γ[m_,n_]:=γ[m,n]=(1/2)(γ[m].γt[n]-γ[n].γt[m]);
γ[m_,n_,p_]:=γ[m,n,p]=(1/6)(γ[m].γt[n].γ[p]+γ[p].γt[m].γ[n]+γ[n].γt[p].γ[m]-γ[n].γt[m].γ[p]-γ[m].γt[p].γ[n]-γ[p].γt[n].γ[m]);
γt[m_,n_,p_]:=γt[m,n,p]=(1/6)(γt[m].γ[n].γt[p]+γt[p].γ[m].γt[n]+γt[n].γ[p].γt[m]-γt[n].γ[m].γt[p]-γt[m].γ[p].γt[n]-γt[p].γ[n].γt[m]);

Check

And@@Flatten@Table[Γ[i].Γ[j]+Γ[j].Γ[i]==2*KroneckerDelta[i,j]*IdentityMatrix[32],{i,10},{j,i,10}]
And@@Flatten@Table[γ[i].γt[j]+γ[j].γt[i]==2*KroneckerDelta[i,j]*IdentityMatrix[16],{i,10},{j,i,10}]
And@@Flatten@Table[γt[i].γ[j]+γt[j].γ[i]==2*KroneckerDelta[i,j]*IdentityMatrix[16],{i,10},{j,i,10}]

And@@Table[ArrayFlatten[{{0*IdentityMatrix[16],γt[ii]},{γ[ii],0*IdentityMatrix[16]}}]==Γ[ii],{ii,0,10}]

Identities of Gamma matrices

LaunchKernels[];
DistributeDefinitions[γ,γt]

(Subscript[γ, m]) with (m,n=0,...9)

And@@Table[γ[i]==Transpose[γ[i]],{i,0,10}]

And@@Flatten@ParallelTable[0==Sum[sigG[m](γ[m][[a,b1]]γ[m][[b2,b3]]+γ[m][[a,b2]]γ[m][[b3,b1]]+γ[m][[a,b3]]γ[m][[b1,b2]]),{m,0,9}],{b1,16},{b2,16},{b3,16},{a,16}]

(Subscript[γ, mn]) with (m,n=0,...9)

And@@And@@@Table[Table[γ[i,j]==-Transpose[γ[i,j]],{i,j}],{j,0,9}]

(* Table[γ[i,10]==-Transpose[γ[i,10]],{i,0,10}] -- False *)

Table[Sum[Sum[sigG[m]sigG[n]γ[m,n][[1,1]]γ[m,n][[b1,b2]],{m,0,9}],{n,0,9}],{b1,2},{b2,2}]

(* γ[m_,n_]:=γ[m,n]=(1/2)(γ[m].γt[n]-γ[n].γt[m]); *)

And@@Flatten@ParallelTable[0==Quiet[Sum[sigG[m]sigG[n]γ[m,n][[a1,a2]]γ[m,n][[b1,b2]],{m,0,9},{n,0,9}]-4Sum[sigG[m]γ[m][[a1,b1]]γt[m][[a2,b2]],{m,0,9}]+2KroneckerDelta[a1,a2]*KroneckerDelta[b1,b2]+8KroneckerDelta[a1,b2]*KroneckerDelta[b1,a2]],{a1,{1}},{a2,16},{b1,16},{b2,16}]

(Subscript[γ, mnp]) with (m,n,p=0,...9)

And@@And@@@Apply[And,ParallelTable[Table[Table[γ[i,j,k]==Conjugate[γ[i,j,k]],{i,j}],{j,k}],{k,0,9}],{2}]
And@@And@@@Apply[And,ParallelTable[Table[Table[γ[i,j,k]==-Transpose[γ[i,j,k]],{i,j}],{j,k}],{k,0,9}],{2}]

And@@And@@@Apply[And,ParallelTable[Table[Table[γt[i,j,k]==Conjugate[γt[i,j,k]],{i,j}],{j,k}],{k,0,9}],{2}]
And@@And@@@Apply[And,ParallelTable[Table[Table[γt[i,j,k]==-Transpose[γt[i,j,k]],{i,j}],{j,k}],{k,0,9}],{2}]

And@@And@@@Apply[And,ParallelTable[Table[Table[γ[i,j,k]==γ[i].γ[j,k]-sigG[i]KroneckerDelta[i,j]γ[k]+sigG[i]KroneckerDelta[i,k]γ[j],{i,j}],{j,k}],{k,0,9}],{2}]
And@@And@@@Apply[And,ParallelTable[Table[Table[γ[i,j,k]==γ[i,j].γ[k]-sigG[j]KroneckerDelta[j,k]γ[i]+sigG[i]KroneckerDelta[i,k]γ[j],{i,j}],{j,k}],{k,0,9}],{2}]

U(5) basis

Finding the highest weight states

Γp[a_]:=Γ[2a-1]+I Γ[2a];
Γm[a_]:=Γ[2a-1]-I Γ[2a];
nullp=Table[NullSpace[Γ[2k-1]+I Γ[2k]],{k,5}];
nullm=Table[NullSpace[Γ[2k-1]-I Γ[2k]],{k,5}];

vecp[1]=Sum[c[i]nullp[[1,i]],{i,16}];
Do[vecp[n_]=vecp[n-1]/.First@Solve[Γp[n].vecp[n-1]==0,Table[c[j],{j,16}]],{n,2,5}]//Quiet;

HWS=vecp[5]/.c[___]->1

U(5) basis

Λp[]=HWS;
Λp[a_,b_]:=(((Γm[a].Γm[b]-Γm[b].Γm[a])/2)).Λp[];
Λp[a_,b_,c_,d_]:=(((Γm[a].Γm[b]-Γm[b].Γm[a])/2)).Λp[c,d];

tab2=Sort/@Part[Permutations[Range[5]],All,;;2]//DeleteDuplicates;
tab4=Sort/@Part[Permutations[Range[5]],All,;;4]//DeleteDuplicates;
tab22=Table[DeleteDuplicates[Join[Sort[#[[;;2]]],Sort[#[[3;;]]]]&/@(Permutations@tab4[[ii]])],{ii,Length@tab4}];
tab4c=Complement[Range[5],#]&/@tab4;

Chiral spinor

Λu=u[] Λp[]+Sum[u[tab2[[ii,1]],tab2[[ii,2]]]Λp[tab2[[ii,1]],tab2[[ii,2]]],{ii,Length@tab2}]+Sum[u[tab4[[ii,1]],tab4[[ii,2]],tab4[[ii,3]],tab4[[ii,4]]]Λp[tab4[[ii,1]],tab4[[ii,2]],tab4[[ii,3]],tab4[[ii,4]]],{ii,Length@tab4}];
λu=Part[Λu,17;;];
λv=λu/.u[any___]:>v[any];

PS constraints

Expanding  (Subscript[λ, u])(Subscript[γ, m])(Subscript[λ, v])=0

tabPS=Expand@Join[Table[((λu.(γ[2k-1]-I γ[2k]).λv)/256),{k,4}],{((λu.(γ[9]-γ[0]).λv)/256)},Table[((λu.(γ[2k-1]+I γ[2k]).λv)/256),{k,4}],{((λu.(γ[9]+γ[0]).λv)/256)}]

Decompose 10 equations into 5+5

tabBilinear=Table[(((-1))^ii)(u[]v@@tab4[[ii]]+u@@tab4[[ii]]v[]-Sum[Signature[tab22[[ii,jj]]]u@@tab22[[ii,jj,;;2]]v@@tab22[[ii,jj,3;;]],{jj,Length@tab22[[ii]]}]),{ii,Length@tab4}];
tabBilinear2=Table[Expand@Sum[-4Signature[Join[tab4c[[ii]],tab4[[ii]]]]Signature[Join[{kk},tab4c[[ii]]]](u@@Sort[Join[{kk},tab4c[[ii]]]]v@@tab4[[ii]]+v@@Sort[Join[{kk},tab4c[[ii]]]]u@@tab4[[ii]]),{ii,Length@tab4}],{kk,5}]/.{u[m_,m_]->0,v[m_,m_]->0};
Complement[tabPS,Join[tabBilinear,tabBilinear2]]

Solving PS constraints, general

General solution is complicated, and not all equations are independent

soluv=Solve[tabPS==0,Join[u@@@tab4,v@@@tab4]]

solu=Solve[tabBilinear==0,u@@@tab4]//FullSimplify

tabBilinear2b=((v[])/4)*tabBilinear2/.First@solu//Expand;

solv=Solve[tabBilinear2b==0,v@@@tab4]//Simplify

Solving PS constraints, specific

tabPSu=tabPS/.v[any___]:>u[any]
Solve[%==0,Join[u@@@tab4]]

tabPSv=tabPS/.{v[]->1,v[any__]:>0}
Solve[%==0,Join[u@@@tab4]]